S3C2440-啟動(dòng)分析
加入技術(shù)交流群
IsrIRQ
sub sp,sp,#4 ；首先在棧中留出一個(gè)字的位置
stmfd sp!,{r8-r9} ；由于要用到r8，r9所以先壓棧，保存
ldr r9,=INTOFFSET ；把INTOFFSET寄存器的地址放入r9中
ldr r9,[r9] ；把r9的內(nèi)容放入r9寄存器中
ldr r8,=HandleEINT0 ；得到中斷向量表的基地址
add r8,r8,r9,lsl #2 ；用基址加變址的方式得到中斷向量表的地址
ldr r8,[r8] ；把中斷處理程序的入口地址放入r8
str r8,[sp,#8] ；將r8壓入棧中
ldmfd sp!,{r8-r9,pc} ； 使r8,r9和入口地址出棧，并跳轉(zhuǎn)到中斷服務(wù)程序中
LTORG
/*******************************************************************
這個(gè)是程序的入口，主要進(jìn)行了關(guān)閉看門(mén)狗，屏蔽所有中斷，設(shè)置時(shí)鐘，設(shè)置內(nèi)存控制，檢查啟動(dòng)方式，如果是Nandflash，進(jìn)行代碼的搬運(yùn)。如果是Norflash，將代碼復(fù)制到RO指定的位置。初始化各個(gè)模式下的堆棧。
*******************************************************************/
;=======
; ENTRY
;=======
ResetHandler
ldr r0,=WTCON
ldr r1,=0x0 ；WTCON的第0位是復(fù)位信號(hào)輸出允許位
str r1,[r0]
ldr r0,=INTMSK
ldr r1,=0xffffffff ；屏蔽所有的中斷
str r1,[r0]
ldr r0,=INTSUBMSK ；屏蔽所有的子中斷
ldr r1,=0x7fff
str r1,[r0]
;led顯示
[ {FALSE}
; rGPFDAT = (rGPFDAT & "(0xf＜＜4)) | (("data & 0xf)＜＜4);
; Led_Display
ldr r0,=GPFCON
ldr r1,=0x5500
str r1,[r0]
ldr r0,=GPFDAT
ldr r1,=0x10
str r1,[r0]
]
/**********************************************************************************
設(shè)置系統(tǒng)時(shí)鐘，主要設(shè)置PLL鎖定時(shí)間和UPLL（USB時(shí)鐘）和MPLL的主頻。S3C2440A的時(shí)鐘控制邏輯有兩個(gè)PLL，一個(gè)是UPLL，一個(gè)是MPLL。MPLL可以產(chǎn)生FCLK（for CPU），HCLK(for AHB bus),PCLK(for APB bus)。
**********************************************************************************/
;To reduce PLL lock time, adjust the LOCKTIME register.
ldr r0,=LOCKTIME
ldr r1,=0xffffff ；復(fù)位后 LOCKTIME 是0xffffffff
str r1,[r0]
[ PLL_ON_START
; Added for confirm clock divide. for 2440.
; Setting value Fclk:Hclkclk
ldr r0,=CLKDIVN
ldr r1,=CLKDIV_VAL ; 0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4, 5=1:4:8, 6=1:3:3, 7=1:3:6. ;設(shè)置分頻值
str r1,[r0]
[ CLKDIV_VAL＞1 ; means Fclk:Hclk is not 1:1.
mrc p15,0,r0,c1,c0,0
orr r0,r0,#0xc0000000;R1_nF:OR:R1_iA
mcr p15,0,r0,c1,c0,0
|
mrc p15,0,r0,c1,c0,0
bic r0,r0,#0xc0000000;R1_iA:OR:R1_nF
mcr p15,0,r0,c1,c0,0
]
;Configure UPLL
ldr r0,=UPLLCON
ldr r1,=((U_MDIV＜＜12)+(U_PDIV＜＜4)+U_SDIV)
str r1,[r0]
nop ; Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting hardware be completed.
nop
nop
nop
nop
nop
nop
;Configure MPLL
ldr r0,=MPLLCON
ldr r1,=((M_MDIV＜＜12)+(M_PDIV＜＜4)+M_SDIV) ;Fin=16.9344MHz
str r1,[r0]
]
;Check if the boot is caused by the wake-up from SLEEP mode.
ldr r1,=GSTATUS2
ldr r0,[r1]
tst r0,#0x2
;In case of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.
bne WAKEUP_SLEEP
; EXPORT StartPointAfterSleepWakeUp
;StartPointAfterSleepWakeUp
;Set memory control registers
;ldr r0,=SMRDATA
adrl r0, SMRDATA
ldr r1,=BWSCON ;BWSCON Address
add r2, r0, #52 ;End address of SMRDATA
0
ldr r3, [r0], #4
str r3, [r1], #4
cmp r2, r0
bne %B0
;delay
mov r0, #&1000
1
subs r0, r0, #1
bne %B1
;===
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;; When EINT0 is pressed, Clear SDRAM
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; check if EIN0 button is pressed
；檢查EIN0按鈕是否被按下
ldr r0,=GPFCON
ldr r1,=0x0
str r1,[r0] ；GPFCON=0，F(xiàn)口為輸入
ldr r0,=GPFUP
ldr r1,=0xff
str r1,[r0] ；GPFUP=0xff，上拉功能無(wú)效
ldr r1,=GPFDAT
ldr r0,[r1] ；讀取F口數(shù)據(jù)
bic r0,r0,#(0x1e＜＜1) ；僅保留第1位數(shù)據(jù)，其他清0
tst r0,#0x1 ；判斷第1位
bne %F1 ；不為0表示按鈕沒(méi)有被按下，則向前跳轉(zhuǎn)，不執(zhí)行清空SDRAM
; Clear SDRAM Start
；清空SDRAM
ldr r0,=GPFCON
ldr r1,=0x55aa
str r1,[r0] ；GPF7"4為輸出，GPF3"0為中斷
; ldr r0,=GPFUP
; ldr r1,=0xff
; str r1,[r0] ；上拉功能無(wú)效
ldr r0,=GPFDAT
ldr r1,=0x0
str r1,[r0] ;GPFDAT = 0
mov r1,#0
mov r2,#0
mov r3,#0
mov r4,#0
mov r5,#0
mov r6,#0
mov r7,#0
mov r8,#0
ldr r9,=0x4000000 ；64MB RAM
ldr r0,=0x30000000 ；RAM首地址
；清空64MB的RAM
0
stmia r0!,{r1-r8}
subs r9,r9,#32
bne %B0
;Clear SDRAM End
1
;Initialize stacks
bl InitStacks
; Setup IRQ handler//建立中斷表
ldr r0,=HandleIRQ ;This routine is needed
ldr r1,=IsrIRQ ;if there isn t subs pc,lr,#4 at 0x18, 0x1c
str r1,[r0]
;===========================================================
;// 判斷是從nor啟動(dòng)還是從nand啟動(dòng)
;===========================================================
；下面的代碼為把ROM中的數(shù)據(jù)復(fù)制到RAM中
ldr r0, =BWSCON
ldr r0, [r0]
ands r0, r0, #6 ；讀取OM[1:0]引腳狀態(tài)
；為0表示從NAND Flash啟動(dòng)，不為0則從NOR Flash啟動(dòng)
bne copy_proc_beg ；跳轉(zhuǎn)，不用讀取NAND Flash
adr r0, ResetEntry ；OM[1:0] == 0，從NAND Flash啟動(dòng)
cmp r0, #0 ;if use Multi-ice,
bne copy_proc_beg ;do not read nand flash for boot
;nop
/*******************************************************************
這里是2440進(jìn)行代碼搬運(yùn)。如果是從Nandflash中啟動(dòng)，首先要把啟動(dòng)代碼的前4k拷貝到稱(chēng)為“SteppingStone”的4kSRAM中，然后在這4k代碼中將剩下的代碼從Nandflash拷貝到SDRAM中。
*******************************************************************/
nand_boot_beg
[ {TRUE}
bl RdNF2SDRAM ；復(fù)制NAND Flash到SDRAM
]
ldr pc, =copy_proc_beg
/*******************************************************************
比較ResetEntry和BaseOfROM，如果相等，在內(nèi)存運(yùn)行ICE，無(wú)需賦值code區(qū)中的RO段，但要復(fù)制code中的RW段。下面這個(gè)針對(duì)代碼在NorFlash時(shí)的拷貝方法。功能為把從ResetEntry起，TopOfROM-BaseOfROM大小的數(shù)據(jù)拷貝到BaseOfROM。TopOfROM和BaseOfROM為|Image$$RO$$Limit|和|Image$$RO$$Base|，|Image$$RO$$Limit|和|Image$$RO$$Base|由連接器生成。為生成的代碼的代碼段運(yùn)行時(shí)的起始和終止地址。開(kāi)始時(shí)r0=RetEntry（source），r2=BaseOfROM(destination)。終止條件：復(fù)制了TopOfROM-BaseOfROM大小。
*******************************************************************/
copy_proc_beg
adr r0, ResetEntry
ldr r2, BaseOfROM
cmp r0, r2
ldreq r0, TopOfROM
beq InitRam
ldr r3, TopOfROM
0
ldmia r0!, {r4-r7}
stmia r2!, {r4-r7}
cmp r2, r3
bcc %B0
sub r2, r2, r3
sub r0, r0, r2
/*******************************************************************
比較BaseOfBSS和BaseOfZero，當(dāng)代碼在內(nèi)存中運(yùn)行時(shí)，r0(初始值)＝TopOfROM，這之后的BaseOfZero-BaseOfBSS仍屬于code，需要拷貝到BaseOfBSS。
*******************************************************************/*
InitRam
ldr r2, BaseOfBS
ldr r3, BaseOfZero
0
cmp r2, r3
ldrcc r1, [r0], #4
strcc r1, [r2], #4
bcc %B0
/*******************************************************************
下面的循環(huán)體是為未初始化的全局變量賦值為0
*******************************************************************/
mov r0, #0
ldr r3, EndOfBSS
1
cmp r2, r3
strcc r0, [r2], #4
bcc %B1
ldr pc, =%F2 ;goto compiler address