1．串行口方式0應(yīng)用編程 8051單片機(jī)串行口方式0為移位寄存器方式，外接一個(gè)串入并出的移位寄存器，就能擴(kuò)展一個(gè)并行口。

單片機(jī)串行口通信程序設(shè)計(jì)硬件連接圖>

例：用8051單片機(jī)串行口外接CD4094擴(kuò)展8位并行輸出口，如圖所示，8位并行口的各位都接一個(gè)發(fā)光二極管，要求發(fā)光管呈流水燈狀態(tài)。 串行口方式0的數(shù)據(jù)傳送可采用中斷方式，也可采用查詢方式，無(wú)論哪種方式，都要借助于TI或RI標(biāo)志。串行發(fā)送時(shí)，能靠TI置位（發(fā)完一幀數(shù)據(jù)后）引起中斷申請(qǐng)，在中斷服務(wù)程序中發(fā)送下一幀數(shù)據(jù)，或者通過(guò)查詢TI的狀態(tài)，只要TI為0就繼續(xù)查詢，TI為1就結(jié)束查詢，發(fā)送下一幀數(shù)據(jù)。在串行接收時(shí)，則由RI引起中斷或?qū)I查詢來(lái)確定何時(shí)接收下一幀數(shù)據(jù)。無(wú)論采用什么方式，在開(kāi)始通信之前，都要先對(duì)控制寄存器SCON進(jìn)行初始化。在方式0中將，將00H送SCON就能了。

-----------------單片機(jī)串行口通信程序設(shè)計(jì)范例--------------------------

ORG 2000H

START: MOV SCON,#00H ;置串行口工作方式0

MOV A,#80H ;最高位燈先亮

CLR P1.0 ;關(guān)閉并行輸出（避象傳輸過(guò)程中，各LED的"暗紅"現(xiàn)象）

OUT0: MOV SBUF,A ;開(kāi)始串行輸出

OUT1: JNB TI,OUT1 ;輸出完否

CLR TI ;完了，清TI標(biāo)志，以備下次發(fā)送

SETB P1.0 ;打開(kāi)并行口輸出

ACALL DELAY ;延時(shí)一段時(shí)間

RR A ;循環(huán)右移

CLR P1.0 ;關(guān)閉并行輸出

JMP OUT0 ;循環(huán)

說(shuō)明：DELAY延時(shí)子程序能用前面我們講P1口流水燈時(shí)用的延時(shí)子程序，這里就不給出了。

二、串行口異步通信

org 0000H

AJMP START

ORG 30H

START:

mov SP,#5fh ;

mov TMOD,#20h ;T1: 工作模式2

mov PCON,#80h ;SMOD=1

mov TH1,#0FDH ;初始化波特率（參見(jiàn)表）

mov SCON,#50h ;Standard UART settings

MOV R0,#0AAH ;準(zhǔn)備送出的數(shù)

SETB REN ;允許接收

SETB TR1 ;T1開(kāi)始工作

WAIT:

MOV A,R0

CPL A

MOV R0,A

MOV SBUF,A

LCALL DELAY

JBC TI,WAIT1 ;如果TI等于1，則清TI并轉(zhuǎn)WAIT1

AJMP WAIT

WAIT1: JBC RI,READ ;如果RI等于1，則清RI并轉(zhuǎn)READ

AJMP WAIT1

READ:

MOV A,SBUF ;將取得的數(shù)送P1口

MOV P1,A

LJMP WAIT

DELAY: ;延時(shí)子程序

MOV R7,#0ffH

DJNZ R7,$

RET

END

將程序編譯通過(guò)，寫入芯片，插入實(shí)驗(yàn)板，用通讀電纜將實(shí)驗(yàn)板與主機(jī)的串行口相連就能實(shí)驗(yàn)了。上面的程序功能很簡(jiǎn)單，就是每隔一段時(shí)間向主機(jī)輪流送數(shù)55H和AAH，并把主機(jī)送去的數(shù)送到P1口。能在PC端用串行口精靈來(lái)做實(shí)驗(yàn)。串行口精靈在我主頁(yè)上有下載。運(yùn)行串行口精靈后，按主界面上的“設(shè)置參數(shù)”按鈕進(jìn)入“設(shè)置參數(shù)”對(duì)話框，按下面的參數(shù)進(jìn)行設(shè)置。注意，我的機(jī)器上用的是串行口2，如果你不是串行口2，請(qǐng)自行更改串行口的設(shè)置。

設(shè)置完后，按確定返回主界面，注意右邊有一個(gè)下拉列表，應(yīng)當(dāng)選中“按16進(jìn)制”。然后按“開(kāi)始發(fā)送”、“開(kāi)始接收”就能了。按此設(shè)置，實(shí)驗(yàn)板上應(yīng)當(dāng)有兩只燈亮，6只燈滅。大家能自行更改設(shè)置參數(shù)中的發(fā)送字符如55，00，F(xiàn)F等等，觀察燈的亮滅，并分析原因，也能在主界面上更改下拉列表中的“按16進(jìn)制”為“按10進(jìn)制”或“按ASCII字符”來(lái)觀察現(xiàn)象，并仔細(xì)分析。這對(duì)于大家理解16進(jìn)制、10進(jìn)制、ASCII字符也是很有好處的。程序本身很簡(jiǎn)單，又有注釋，這里就不詳加說(shuō)明了。

三、上述程序的中斷版本

org 0000H

AJMP START

org 0023h

AJMP SERIAL ;

ORG 30H

START:

mov SP,#5fh ;

mov TMOD,#20h ;T1: 工作模式2

mov PCON,#80h ;SMOD=1

mov TH1,#0FDH ;初始化波特率（參見(jiàn)表）

mov SCON,#50h ;Standard UART settings

MOV R0,#0AAH ;準(zhǔn)備送出的數(shù)

SETB REN ;允許接收

SETB TR1 ;T1開(kāi)始工作

SETB EA ;開(kāi)總中斷

SETB ES ;開(kāi)串行口中斷

SJMP $

SERIAL:

MOV A,SBUF

MOV P1,A

CLR RI

RETI

END

本程序沒(méi)有寫入發(fā)送程序，大家能自行添加。