從實(shí)際出發(fā),設(shè)計(jì)一種家庭用、與電話(huà)線(xiàn)連接、操作簡(jiǎn)單、工作穩(wěn)定可靠的遠(yuǎn)程智能防盜報(bào)警裝置。當(dāng)人們外出時(shí),往往希望實(shí)施自動(dòng)監(jiān)測(cè)報(bào)警以使家庭財(cái)產(chǎn)免受損失。針對(duì)這一需求,研制出了一系列自動(dòng)報(bào)警系統(tǒng),如門(mén)磁式、觸摸式和紅外線(xiàn)監(jiān)測(cè)自動(dòng)報(bào)警系統(tǒng)等。本文將介紹的遠(yuǎn)程智能防盜報(bào)警裝置,可同時(shí)監(jiān)視多個(gè)重要點(diǎn)（如門(mén)、窗等）,發(fā)現(xiàn)盜情及時(shí)撥叫號(hào)碼,并能利用普通電話(huà)線(xiàn)進(jìn)行告警信號(hào)呼叫,其性能穩(wěn)定可靠,實(shí)用性、適用性強(qiáng),且具有較高的靈活性。

基于單片機(jī)汽車(chē)防盜器報(bào)警聲的源程序

;ST套件產(chǎn)生汽車(chē)防盜器報(bào)警聲
;本實(shí)例的目的是讓大家學(xué)會(huì)用單片機(jī)產(chǎn)生聲音的方法，學(xué)會(huì)計(jì)算程序所用時(shí)間
;本實(shí)例的功能是能PIC16F84產(chǎn)生汽車(chē)防盜器的報(bào)警聲，頻率分兩個(gè)0.1s第一個(gè)
;0.1S頻率從1.8K-3.5K勻速增加第二個(gè)0.1S頻率從3.5K-1.8K勻速減少,
;程序復(fù)位后,按S2喇叭叫兩聲,按S3喇叭叫15秒,中途可按S5停止.
;PIC單片機(jī)學(xué)習(xí)網(wǎng)
;燒寫(xiě)時(shí)應(yīng)注意：配置位已經(jīng)在程序中寫(xiě)明，加載HEX文件時(shí)會(huì)自動(dòng)加載，燒寫(xiě)時(shí)不用再手動(dòng)設(shè)置配置位。
;實(shí)驗(yàn)時(shí)請(qǐng)注意套件跳線(xiàn)選擇；
;*****************************************************
LIST P=16F84A,R=DEC ;定義器件,默認(rèn)為十進(jìn)制
;-----------------------------------------------------
__CONFIG B'11111111110001';_CP_OFF_WDT_OFF_PWRITE_ON_XT_OSC
;沒(méi)有代碼保護(hù)
;看門(mén)狗關(guān)閉
;上電廷時(shí)器開(kāi)啟
;振蕩器模式為XT
;-----------------------------------------------------
RTCC EQU 01H ;定義各寄存器
PC EQU 02H
STATUS EQU 03H
C EQU 0
RP0 EQU 5
;----------------------
PORTA EQU 05H
PORTB EQU 06H

TRISA EQU 5H
TRISB EQU 6H
;-----------------------
SOUNDDELAY1 EQU 10H ;聲音頻率變化計(jì)數(shù)器，從1.8~3.55KHZ
FRE_COUNT EQU 11H ;同一頻率的重復(fù)次數(shù)保存地址
FRE_REPEAT EQU 12H
SOUND_TEMP EQU 13H
TEMP EQU 14H ;暫存寄存器
S_LOOP EQU 46 ;93-47=46
S_MAX EQU 93 ;最低頻率1.8K 93*3=280US*2
S_MIN EQU 47 ;最高頻率3.55K 47*3=140*2
S_REPEAT EQU 4 ;同一頻率重復(fù)次數(shù)
;----------------------RA
KEY1 EQU 3
KEY2 EQU 4
;----------------------RB
KEY3 EQU 0
KEY4 EQU 1
;--------------------
ORG 0000H
MAIN
CLRF PORTA
CLRF PORTB ;初始化IO口

BSF STATUS,RP0 ;設(shè)置數(shù)據(jù)寄存器體1
MOVLW 0011000B
MOVWF TRISA ;設(shè)置各開(kāi)關(guān)端口為輸入其它為輸出
MOVLW 00000011B
MOVWF TRISB
BCF STATUS,RP0 ;恢復(fù)數(shù)據(jù)寄存器體0
LOOP
BTFSS PORTA,KEY1 ;掃描按鍵
GOTO SET_1
BTFSS PORTA,KEY2
GOTO SET_2
GOTO LOOP
;--------------------------------------------
SET_1
BTFSC PORTA,KEY1 ;去抖動(dòng)
GOTO LOOP
CALL SOUNDDELAY
BTFSC PORTA,KEY1 ;按S2叫兩聲
GOTO LOOP
CALL SOUND200MS
CALL SOUND200MS
GOTO LOOP
;--------------------------------------------
SET_2
BTFSC PORTA,KEY2 ;去抖動(dòng)
GOTO LOOP
CALL SOUNDDELAY
BTFSC PORTA,KEY2 ;按S3叫15秒
GOTO LOOP
CALL SOUND15S
GOTO LOOP
;- - ----------------------------------------
SOUND200MS
MOVLW S_LOOP
MOVWF FRE_COUNT ;46=93-47
SOUND_LH_LP
MOVLW S_REPEAT ;同一頻率重復(fù)次數(shù)送FRE_REPEAT
MOVWF FRE_REPEAT
MOVFW FRE_COUNT
ADDLW S_MIN ;計(jì)數(shù)值加最小值
MOVWF TEMP
REPEAT0_LP
MOVFW TEMP
BSF PORTA,0
CALL SOUNDDELAY0 ;廷時(shí)W*3US
BCF PORTA,0
MOVFW TEMP
CALL SOUNDDELAY0
DECFSZ FRE_REPEAT,1 ;每四次減頻率計(jì)數(shù)一次
GOTO REPEAT0_LP
DECFSZ FRE_COUNT,1
GOTO SOUND_LH_LP
SOUND_HL
MOVLW S_LOOP
MOVWF FRE_COUNT ;46=93-47
SOUND_HL_LP
MOVLW S_REPEAT ;同一頻率重復(fù)次數(shù)送FRE_REPEAT
MOVWF FRE_REPEAT
MOVFW FRE_COUNT
SUBLW S_MAX ;最大值減計(jì)數(shù)值
MOVWF TEMP
REPEAT1_LP
MOVFW TEMP
BSF PORTA,0
CALL SOUNDDELAY0 ;廷時(shí)W*3US
BCF PORTA,0
MOVFW TEMP
CALL SOUNDDELAY0
DECFSZ FRE_REPEAT,1;四次減頻率計(jì)數(shù)一次
GOTO REPEAT1_LP
DECFSZ FRE_COUNT,1
GOTO SOUND_HL_LP
SOUND_END
RETLW 0
;------------------------------
SOUNDDELAY: ;廷時(shí)255*3US+2US
MOVLW 255
SOUNDDELAY0
MOVWF SOUNDDELAY1 ;廷時(shí)W*3US+1US
SOUNDDELAYUS_1
DECFSZ SOUNDDELAY1,1
GOTO SOUNDDELAYUS_1
RETLW 0
;---------------------
SOUND15S ;報(bào)警15秒
MOVLW 73
MOVWF SOUND_TEMP
SOUND1S_LP
CALL SOUND200MS
BTFSS PORTB,KEY4 ;按S5退出
RETLW 0
DECFSZ SOUND_TEMP,1
GOTO SOUND1S_LP
RETLW 0
;------------------------
END