; NAME: 2440INIT.S

; DESC: C start up codes

; Configure memory, ISR ,stacks

;Initialize C-variables

;=========================================

;注意：axd調(diào)試時(shí)，可以看到指令pc地址從0x30000000開(kāi)始，這是因?yàn)閞am的起始地址是0x30000000.

;并且如果從nand啟動(dòng)，則處理器自動(dòng)把nand首部的4k字節(jié)，復(fù)制到ram中，然后pc跳到0x30000000，開(kāi)始執(zhí)行。

;此源文件通常包含一些宏定義和常量定義

;通用的《啟動(dòng)流程圖》：

;入口->屏蔽所有中斷，禁止看門狗->根據(jù)工作頻率設(shè)置PLL寄存器->初始化存儲(chǔ)控制相關(guān)寄存器

;->初始化各模式下的棧指針->設(shè)置缺省中斷處理函數(shù)->將數(shù)據(jù)拷貝到RAM中，數(shù)據(jù)段清零

;->跳轉(zhuǎn)到c語(yǔ)言main入口函數(shù)中

;GET偽指令用于將一個(gè)源文件包含到當(dāng)前源文件中，并將被包含文件在當(dāng)前位置進(jìn)行匯編處理

;類似于c的include指令

;GET INLCUDE偽指令不能用來(lái)包含目標(biāo)文件，INCBIN偽指令可以包含目標(biāo)文件,

;被INCBIN偽指令包含的文件，不進(jìn)行匯編處理，該執(zhí)行文件或數(shù)據(jù)直接放入當(dāng)前文件，

;編譯器從INCBIN后邊開(kāi)始繼續(xù)處理

GET option.inc ;定義芯片相關(guān)配置

GET memcfg.inc ;定義存儲(chǔ)器配置

GET 2440addr.inc ;定義寄存器符號(hào)

;REFRESH寄存器[22]bit :SDRAM刷新模式 0 - auto refresh

; 1 - self refresh

;用于節(jié)電模式中，SDRAM自動(dòng)刷新

BIT_SELFREFRESH EQU (1<<22)

;Pre-defined constants

;模式預(yù)定義常量，給cpsr【4-0】賦值，改變運(yùn)行模式

USERMODE EQU 0x10

FIQMODE EQU 0x11

IRQMODE EQU 0x12

SVCMODE EQU 0x13

ABORTMODE EQU 0x17

UNDEFMODE EQU 0x1b

MODEMASK EQU 0x1f ;模式屏蔽位

NOINT EQU 0xc0 ;1100 0000,中斷屏蔽掩碼

;The location of stacks

;0x30000000 = 768M

;定義各模式下的堆棧常量，是一個(gè)遞減棧，后邊標(biāo)上了各個(gè)棧的大小

UserStack EQU (_STACK_BASEADDRESS-0x3800) ; ~ 0x33ff4800 大小不定，跟堆大小相對(duì)應(yīng)

;畢竟是用戶態(tài)棧

SVCStack EQU (_STACK_BASEADDRESS-0x2800) ; ~ 0x33ff5800 4M

UndefStack EQU (_STACK_BASEADDRESS-0x2400) ; ~ 0x33ff5c00 1M

AbortStack EQU (_STACK_BASEADDRESS-0x2000) ; ~ 0x33ff6000 1M

IRQStack EQU (_STACK_BASEADDRESS-0x1000) ; ~ 0x33ff7000 4M

FIQStack EQU (_STACK_BASEADDRESS-0x0) ; ~ 0x33ff8000 4M

;處理器分為16位 32位兩種工作狀態(tài)程序的編譯器也是分16位和32兩種編譯方式

;下面程序根據(jù)處理器工作狀態(tài)確定編譯器編譯方式

;code16偽指令指示匯編編譯器后面的指令為16位的thumb指令

;code32偽指令指示匯編編譯器后面的指令為32位的arm指令

;Arm上電時(shí)處于ARM狀態(tài)，故無(wú)論指令為ARM集或Thumb集，都先強(qiáng)制成ARM集，待init.s初始化完成后,再根據(jù)用

;戶的編譯配置轉(zhuǎn)換成相應(yīng)的指令模式。為此，定義變量THUMBCODE作為指示，跳轉(zhuǎn)到main之前根據(jù)其值切換指令

;模式

;Check if tasm.exe(armasm -16 ...@ADS 1.0)is used.

;檢測(cè)工作模式，根據(jù)CONFIG的數(shù)值，確定工作模式

;{CONFIG}應(yīng)該來(lái)自于ADS環(huán)境，在本環(huán)境中設(shè)置是進(jìn)入時(shí)在ARM環(huán)境下，沒(méi)有設(shè)置ARM/THUMB混合環(huán)境

;關(guān)于是否設(shè)置混合編程，在環(huán)境設(shè)置選項(xiàng)里的ARM Assembler 選項(xiàng)下，由ATPCS -> ARM/Thumb interworking選

;項(xiàng)負(fù)責(zé)

;IF ELSE ENDIF指令

;[ 為 IF ; | 為 ELSE ; ] 為 ENDIF

GBLL THUMBCODE

[{CONFIG} = 16

THUMBCODE SETL {TRUE} ;如果設(shè)置了config，則允許thumb指令，

;但THUMBCODE為真并不表明以下就是thumb指令，只是允許

CODE32 ;code32表示以下是arm指令，在處理器剛開(kāi)始時(shí)，必須以arm模式運(yùn)行

| ;此處容易產(chǎn)生錯(cuò)覺(jué)，丟掉CODE32這一行

THUMBCODE SETL {FALSE}

]

;bx是帶狀態(tài)切換的跳轉(zhuǎn)指令，跳轉(zhuǎn)到Rm指定的地址執(zhí)行程序，若Rm的位[0]為1，則跳轉(zhuǎn)時(shí)自動(dòng)將CPSR的標(biāo)志T

;T置位，即把目標(biāo)地址的代碼解釋為Thumb代碼；若Rm的位[0]為0，則跳轉(zhuǎn)時(shí)自動(dòng)將CPSR中的標(biāo)志T復(fù)位，即把

;目標(biāo)地址的代碼解釋為ARM代碼

;定義兩個(gè)宏，宏的作用：子函數(shù)返回（無(wú)條件，有條件）。

MACRO

MOV_PC_LR

[ THUMBCODE ;如果允許thumb指令，則需要根據(jù)最低位設(shè)置狀態(tài)。

bx lr ;跳轉(zhuǎn)，附帶狀態(tài)切換

|

mov pc,lr

]

MEND

MACRO

MOVEQ_PC_LR ;相等則跳轉(zhuǎn)，相等與否由寄存器某些位確定，在此處，有其上一句的指令執(zhí)行結(jié)果決定

[ THUMBCODE

bxeq lr

|

moveq pc,lr

]

MEND

;MACRO和MEND偽指令用于宏定義，MACRO標(biāo)識(shí)開(kāi)始，MEND標(biāo)識(shí)結(jié)束。用MACRO和MEND定義的一段代碼，稱為宏定義

;體，這樣在程序中就可以通過(guò)宏指令多次調(diào)用該代碼段。

;偽指令格式：

;MACRO

;{$label} macroname {$parameter} {$parameter} ...

;宏定義體

;MEND

;其中 $label 宏指令被展開(kāi)時(shí)，label可被替換成相應(yīng)的符號(hào)，通常為一個(gè)標(biāo)號(hào)，

;在一個(gè)標(biāo)號(hào)前使用$表示被匯編時(shí)將使用相應(yīng)的值替代$后的符號(hào)。

;macroname 所定義的宏的名稱

;$parameter 宏指令的參數(shù)，當(dāng)宏指令被展開(kāi)時(shí)將被替換成相應(yīng)的值，類似于函數(shù)中的形式參數(shù)

;對(duì)于子程序代碼較短，而需要傳遞的參數(shù)比較多的情況下，可以使用匯編技術(shù)。

;首先要用MACRO和MEND偽指令定義宏，包括宏定義體代碼。在MACRO偽指令之后的第一行定義宏的原型，其中包

;含該宏定義的名稱，及需要的參數(shù)。在匯編程序中可以通過(guò)該宏定義的名稱來(lái)調(diào)用它，當(dāng)源程序被匯編時(shí)，匯

;編編譯器將展開(kāi)每個(gè)宏調(diào)用，用宏定義體代替源程序中的宏定義的名稱，并用實(shí)際的參數(shù)值代替宏定義時(shí)的形

;式參數(shù)

;注意：滿遞減指的是在入棧時(shí)的操作方式，在出棧時(shí)則正好相反的次序

;例子：

;STMFD sp!,{R0-R7,LR}:（滿遞減：先減再放數(shù)值）sp根據(jù)數(shù)據(jù)個(gè)數(shù)，減小相應(yīng)個(gè)數(shù)值的數(shù)據(jù)單位（一步到

;位），然后利用for循環(huán)語(yǔ)句，從當(dāng)前sp位置，依次存儲(chǔ)R0-R7,LR.即：sp處最后指向的是R0數(shù)據(jù)處

;LDMFD sp!,{R0-R7,LR}:復(fù)制一個(gè)變量為sp值，用該變量依次將數(shù)據(jù)存入R0-R7,LR，變量值增加，最后，變量指

;向下一個(gè)將要取的值，完成后sp獲得該變量值；

;重點(diǎn)分析下面這個(gè)宏，它對(duì)中斷處理函數(shù)的調(diào)用很重要

;確切說(shuō)，這是宏函數(shù)，編譯時(shí)對(duì)調(diào)用語(yǔ)句要做相應(yīng)的展開(kāi)

MACRO

$HandlerLabel HANDLER $HandleLabel

$HandlerLabel ;標(biāo)號(hào)

sub sp,sp,#4 ;留出一個(gè)空間，為了存放跳轉(zhuǎn)地址給pc。

stmfd sp!,{r0} ;把r0中的內(nèi)容入棧，保存起來(lái)

ldr r0,=$HandleLabel ;這是一個(gè)偽指令，不是匯編指令，

;目的：把$HandleLabel本身所在的地址給r0

ldr r0,[r0] ;把$HandleLabel所指向的內(nèi)容(也就是中斷程序的入口地址)放入r0

str r0,[sp,#4] ;把入口地址放入剛才留出的一個(gè)空間里

ldmfd sp!,{r0,pc} ;出棧的方式恢復(fù)r0原值和為pc設(shè)定新值(也就完成了到ISR的轉(zhuǎn)跳)。

;注：棧中r0內(nèi)容在低地址

MEND

;下面幾個(gè)變量是ads環(huán)境下自動(dòng)設(shè)置的，可以見(jiàn)環(huán)境配置選項(xiàng)里：ARM Linker->Output下，RO Base，RW Base

;IMPORT 引用變量

IMPORT |Image$$RO$$Base| ; Base of ROM code

IMPORT |Image$$RO$$Limit| ; End of ROM code (=start of ROM data)

IMPORT |Image$$RW$$Base| ; Base of RAM to initialise

IMPORT |Image$$ZI$$Base| ; Base and limit of area to zero initialise

IMPORT |Image$$ZI$$Limit|

IMPORT MMU_SetAsyncBusMode

IMPORT MMU_SetFastBusMode ;想知道代碼具體內(nèi)容見(jiàn)cp15手冊(cè)，并以cp15指令內(nèi)容搜索2440a手冊(cè)

IMPORT Main ;The main entry of mon program

IMPORT RdNF2SDRAM ;Copy Image from Nand Flash to SDRAM

;-------------------------------------------------------------------------------------------------

;AREA偽指令用于定義一個(gè)代碼段或數(shù)據(jù)段，一個(gè)ARM源程序至少需要一個(gè)代碼段，大的程序可以包含多個(gè)代碼段

;及數(shù)據(jù)段

;格式：AREA sectionname {,attr} {,attr}...

AREA Init,CODE,READONLY

;ENTRY偽指令用于指定程序的入口點(diǎn)

;一個(gè)程序（可以包含多個(gè)源文件）中至少要有一個(gè)ENTRY，可以有多個(gè)ENTRY，但一個(gè)源文件中最多只有一個(gè)

;ENTRY.

ENTRY

;EXPORT聲明一個(gè)符號(hào)可以被其他文件引用，相當(dāng)于聲明了一個(gè)全局變量。GLOBAL與EXPORT相同

;格式：EXPORT symbol{[WEAK]} [WEAK]聲明其他的同名符優(yōu)先于本符號(hào)被引用

;導(dǎo)出符號(hào)__ENTRY

EXPORT __ENTRY

__ENTRY

ResetEntry

;1)The code, which converts to Big-endian, should be in little endian code.

;2)The following little endian code will be compiled in Big-Endian mode.

; The code byte order should be changed as thememory bus width.

;3)Thepseudo instruction,DCD can not be used here because the linker generates error.

;條件編譯，在編譯成機(jī)器碼前就設(shè)定好大小端轉(zhuǎn)換

;判斷ENDIAN_CHANGE是否已定義，ASSERT 是斷言偽指令,語(yǔ)法是:ASSERT + 邏輯表達(dá)式，def 是邏輯偽操作符，

;格式為：:DEF:label，作用是：判斷l(xiāng)abel是否定義過(guò)

ASSERT :DEF:ENDIAN_CHANGE

[ ENDIAN_CHANGE ;在 option.inc 有定義。默認(rèn)是FALSE，所以此句不會(huì)加入代碼中

ASSERT :DEF:ENTRY_BUS_WIDTH ;斷言指令，檢測(cè)是否定義該變量，若未定義，報(bào)錯(cuò)

[ ENTRY_BUS_WIDTH=32 ;defined in option.inc

b ChangeBigEndian ;DCD 0xea000007

;如果是大端，則這是第一條指令，先設(shè)置成大端，

;再到復(fù)位指令

]

[ ENTRY_BUS_WIDTH=16

andeq r14,r7,r0,lsl #20 ;DCD 0x0007ea00

]

[ ENTRY_BUS_WIDTH=8

streq r0,[r0,-r10,ror #1] ;DCD 0x070000ea

]

|

b ResetHandler ;本硬件用的是小端模式，這是第一個(gè)執(zhí)行語(yǔ)句，

;直接跳轉(zhuǎn)到復(fù)位指令處 0X00

]

;這7個(gè)中斷，每個(gè)中斷都有固定的中斷入口地址，它們位于代碼的最前端，不允許另作他用

b HandlerUndef ;handler for Undefined mode 0X04

b HandlerSWI ;handlerfor SWI interrupt 0X08

b HandlerPabort ;handler for PAbort，指令預(yù)取中止 0X0C

b HandlerDabort ;handler for DAbort，數(shù)據(jù)中止 0X10

b . ;reserved 保留未用 注意小圓點(diǎn) 0X14

b HandlerIRQ ;handlerfor IRQ interrupt 0X18

b HandlerFIQ ;handlerfor FIQ interrupt 0X1C

;@0x20

b EnterPWDN ;Must be @0x20

;------------------------------------------------------------------------------------------------

;下面是改變大小端的程序,采用直接定義 <機(jī)器碼> 的方式,為什么這么做就得問(wèn)三星了

;反正我們程序里這段代碼也不會(huì)去執(zhí)行,不用去管它

;每一個(gè)匯編指令，都對(duì)應(yīng)著一個(gè)二進(jìn)制機(jī)器碼，這里沒(méi)有使用指令，直接用了機(jī)器碼，含義未知

ChangeBigEndian

;@0x24

;對(duì)存儲(chǔ)器控制寄存器操作，指定內(nèi)存模式為Big-endian

;因?yàn)閯傞_(kāi)始CPU都是按照32位總線的指令格式運(yùn)行的，如果采用其他的話，CPU運(yùn)行不了，必須轉(zhuǎn)化

;但當(dāng)系統(tǒng)初始化好以后，則CPU能自動(dòng)識(shí)別

[ ENTRY_BUS_WIDTH=32

DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0

DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80; //Big-endian

DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0

]

[ ENTRY_BUS_WIDTH=16

DCD 0x0f10ee11

DCD 0x0080e380

DCD 0x0f10ee01

]

[ ENTRY_BUS_WIDTH=8

DCD 0x100f11ee

DCD 0x800080e3

DCD 0x100f01ee

]

DCD 0xffffffff ;swinv 0xffffff is similarwith NOP and run well in both endian mode.

DCD 0xffffffff

DCD 0xffffffff

DCD 0xffffffff

DCD 0xffffffff

b ResetHandler ;設(shè)置成大端后，再次跳到復(fù)位指令處

;本文件底部定義了一個(gè)數(shù)據(jù)區(qū)（在文件最后），34個(gè)字空間，存放相應(yīng)中斷服務(wù)程序的首地址。每個(gè)字空間都

;有一個(gè)標(biāo)號(hào)，以Handle***命名。

;這是宏實(shí)例,在這里Handler***就是通過(guò)HANDLER這個(gè)宏和Handle***建立聯(lián)系的.

;詳細(xì)分析：

;Handle*** 這是宏示例，也就是宏的調(diào)用指令，當(dāng)編譯時(shí)編譯器會(huì)把宏調(diào)用指令展開(kāi)

;Handler*** 這是向量中斷

;展開(kāi)方式(舉例)：

;HandlerFIQ HANDLER HandleFIQ

;展開(kāi)后變成：

;標(biāo)號(hào)HandlerFIQ，由 " b HandlerFIQ "指令使用(見(jiàn)上，復(fù)位處)

; sub sp,sp,#4

;留出一個(gè)空間，為了存放跳轉(zhuǎn)地址給pc。見(jiàn)：str r0,[sp,#4] ，注意sp值并未改變

; stmfd sp!,{r0}

;把r0中的內(nèi)容入棧，保存起來(lái)

; ldr r0,=HandleFIQ

;HandleFIQ標(biāo)號(hào)，在本文件最下方定義

; ldr r0,[r0]

;把 HandleFIQ所指向的內(nèi)容(也就是中斷程序的入口地址)放入r0

; str r0,[sp,#4]

;把入口地址放入剛才留出的一個(gè)空間里

; ldmfd sp!,{r0,pc}

;出棧的方式恢復(fù)r0原值和為pc設(shè)定新值(也就完成了到ISR的轉(zhuǎn)跳)。注：棧中r0內(nèi)容在低地址

;后邊的語(yǔ)句展開(kāi)方式，同上。編譯后，代碼都展開(kāi)放置

HandlerFIQ HANDLER HandleFIQ

HandlerIRQ HANDLER HandleIRQ

HandlerUndef HANDLER HandleUndef

HandlerSWI HANDLER HandleSWI

HandlerDabort HANDLER HandleDabort

HandlerPabort HANDLER HandlePabort

;非向量中斷總?cè)肟冢ㄐ枰约号袛嘀袛囝愋?，而不是直接跳轉(zhuǎn)到相應(yīng)程序）

;產(chǎn)生中斷后，需要中斷服務(wù)程序自己來(lái)判斷，到底是哪個(gè)中斷請(qǐng)求，根據(jù)的就是INTOFFSET寄存器中的偏移，再

;計(jì)算中斷服務(wù)地址

IsrIRQ

sub sp,sp,#4 ;reserved for PC,預(yù)留返回指針的存儲(chǔ)位置

stmfd sp!,{r8-r9}

ldr r9,=INTOFFSET ;the interrupt request source offset

ldr r9,[r9]

ldr r8,=HandleEINT0 ;HandleEINT0 ，在本文件最下邊定義的

add r8,r8,r9,lsl #2 ;r9中只是偏移單位的個(gè)數(shù)，需要*4變成具體字節(jié)偏移（相對(duì)于EINT0）

ldr r8,[r8]

str r8,[sp,#8] ;pc值放在了高位置

ldmfd sp!,{r8-r9,pc}

LTORG

;=======

; ENTRY

;=======

ResetHandler

;關(guān)看門狗

ldr r0,=WTCON ;watch dog disable 編譯時(shí)就是 ldr r0,=53000000;偽指令有=號(hào)

ldr r1,=0x0 ;這些宏定義都位于2440addr.inc中。 區(qū)分：變量定義 && 宏定義

str r1,[r0]

;屏蔽所有中斷

ldr r0,=INTMSK ;在 INTMSK 寄存器設(shè)置屏蔽所有中斷

ldr r1,=0xffffffff ;all interrupt disable 要理解子中斷和中斷之間的關(guān)系

str r1,[r0]

ldr r0,=INTSUBMSK ;INTSUBMSK子中斷屏蔽寄存器，屏蔽所有子中斷

ldr r1,=0x7fff ;allsub interrupt disable

str r1,[r0]

[ {FALSE}

;rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);

;Led_Display

ldr r0,=GPBCON

ldr r1,=0x00555555

str r1,[r0]

ldr r0,=GPBDAT

ldr r1,=0x07fe

str r1,[r0]

]

;鎖相環(huán) PLL ,作用是將外部晶振的輸入頻率倍頻到一個(gè)較高的頻率

;To reduce PLL lock time, adjust the LOCKTIME register.

ldr r0,=LOCKTIME ;LOCKTIME鎖定時(shí)間計(jì)數(shù)寄存器

ldr r1,=0xffffff

str r1,[r0]

[ PLL_ON_START ;defined inoption.inc {TRUE},選擇要不要設(shè)置頻率值

;Added for confirm clock divide. for 2440.

;Setting value Fclk:Hclk:Pclk

ldr r0,=CLKDIVN ;CLKDIVN 時(shí)鐘分頻控制寄存器

ldr r1,=CLKDIV_VAL ;0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4,

;5=1:4:8,6=1:3:3, 7=1:3:6.

str r1,[r0]

;programhas not been copied, so use these directly

[ CLKDIV_VAL>1 ; means Fclk:Hclk is not 1:1.

;Fclk為cpu的運(yùn)行時(shí)鐘，Hclk驅(qū)動(dòng) AHB總線設(shè)備（例如：SDRAM）

mrc p15,0,r0,c1,c0,0

orr r0,r0,#0xc0000000 ;R1_nF:OR:R1_iA

mcr p15,0,r0,c1,c0,0

|

mrc p15,0,r0,c1,c0,0

bic r0,r0,#0xc0000000 ;R1_iA:OR:R1_nF

mcr p15,0,r0,c1,c0,0

]

;在配置UPLLCON和MPLLCON寄存器時(shí)，必須先配置UPLLCON，然后再配置MPLLCON，而且兩者之間要有7 nop的間

;隔。（這是2440文檔明確要求的）

;Configure UPLL

ldr r0,=UPLLCON ;UPLLCON: UPLL configuration register

ldr r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV) ;Fin = 12.0MHz, UCLK =48MHz,

;對(duì)于usb來(lái)說(shuō)必須是48MHz

str r1,[r0]

nop ; Caution: After UPLL setting, at least7-clocks delay must be inserted

; for setting hardware be completed.

nop

nop

nop

nop

nop

nop

;Configure MPLL

ldr r0,=MPLLCON ;MPLLCON: MPLL configuration register

ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) ;Fin = 12.0MHz, FCLK= 400MHz

str r1,[r0]

]

;Check if the boot is caused by the wake-up from SLEEP mode.

ldr r1,=GSTATUS2 ;這個(gè)寄存器數(shù)值表示哪個(gè)信號(hào)引起的復(fù)位動(dòng)作產(chǎn)生

;檢測(cè) GSTATUS2[2]來(lái)判斷是否是由 sleep 模式喚醒引起的電源開(kāi)啟。

ldr r0,[r1]

tst r0,#0x2

;Incase of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.

bne WAKEUP_SLEEP

EXPORT StartPointAfterSleepWakeUp

StartPointAfterSleepWakeUp

;Set memory control registers

;ldr r0,=SMRDATA ;(等效于下邊的指令)

adrl r0,SMRDATA ;be careful!中等范圍的地址讀取偽指令，

;用法類似于ldr（大范圍地址讀?。﹤沃噶?/div>