ARM有7種運行Mode，每一種Mode的堆棧指針寄存器(SP)都是獨立的。

所以，對于程序中需要用的每一種處理器模式，都要給SP定義一個堆棧地址。

初始化流程為：

修改狀態(tài)寄存器內(nèi)的狀態(tài)位，使處理器切換到需要的模式

給SP賦值。

注意：

不要切換到User模式進行該模式下的堆棧設置，因為進入User模式后就不能再操作CPSR返回到其他模式了。

===============================

先定義各種模式對應的CPSR寄存器M[4:0]的值，該值決定了進入何種模式，可參考相關(guān)數(shù)據(jù)手冊。

Mode_USR EQU 0x10
Mode_FIQ EQU 0x11
Mode_IRQ EQU 0x12
Mode_SVC EQU 0x13
Mode_ABT EQU 0x17
Mode_UND EQU 0x1B
Mode_SYS EQU 0x1F
I_BIT EQU 0x80 ; when I bit is set (1), IRQ is disabled
F_BIT EQU 0x40 ; when F bit is set (1), FIQ is disabled

下面是初始化堆棧的代碼段：

InitStack
MOV R0, LR

; /* 設置管理模式堆棧 */
MSR CPSR_c, #(Mode_SVC | I_BIT | F_BIT) ; 0xd3
LDR SP,StackSvc
; /* 設置中斷模式堆棧 */
MSR CPSR_c, #(Mode_IRQ | I_BIT | F_BIT); 0xd2
LDR SP,StackIrq
; /* 設置快速中斷模式堆棧 */
MSR CPSR_c, #(Mode_FIQ | I_BIT | F_BIT); 0xd1
LDR SP,StackFiq
; /* 設置中止模式堆棧 */
MSR CPSR_c, #(Mode_ABT | I_BIT | F_BIT); 0xd7
LDR SP,StackAbt
; /* 設置未定義模式堆棧 */
MSR CPSR_c, #(Mode_UND | I_BIT | F_BIT); 0xdb
LDR SP,StackUnd
; /*設置系統(tǒng)模式堆棧*/
MSR CPSR_c, #(Mode_SYS | I_BIT | F_BIT); 0xdf
LDR SP,StackUsr

MOV PC, R0

StackUsr DCD UsrStackSpace + (USR_STACK_LEGTH - 1) * 4
StackSvc DCD SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4
StackIrq DCD IrqStackSpace + (IRQ_STACK_LEGTH - 1)* 4
StackFiq DCD FiqStackSpace + (FIQ_STACK_LEGTH - 1)* 4
StackAbt DCD AbtStackSpace + (ABT_STACK_LEGTH - 1)* 4
StackUnd DCD UndtStackSpace + (UND_STACK_LEGTH - 1)* 4

; /* 分配堆?？臻g */
AREA MyStacks, DATA, NOINIT, ALIGN=2
UsrStackSpace SPACE USR_STACK_LEGTH * 4 ;用戶（系統(tǒng)）模式堆棧空間
SvcStackSpace SPACE SVC_STACK_LEGTH * 4 ;管理模式堆?？臻g
IrqStackSpace SPACE IRQ_STACK_LEGTH * 4 ;中斷模式堆?？臻g
FiqStackSpace SPACE FIQ_STACK_LEGTH * 4 ;快速中斷模式堆?？臻g
AbtStackSpace SPACE ABT_STACK_LEGTH * 4 ;中止義模式堆棧空間
UndtStackSpace SPACE UND_STACK_LEGTH * 4 ;未定義模式堆棧

===============================

以管理模式堆?？臻g為例說明一下：

SVC_STACK_LEGTH 定義為 16 ，分配結(jié)果為：分配16個4字節(jié)的存儲空間，把該存儲空間初始化為0，并且把SP指向堆棧底部（內(nèi)存高位）。

從上面memory的內(nèi)容上面可以看出。管理模式堆棧分配了從0x00008080~0x00008044 一共16*4字節(jié)空間。其中0x00008040地址存儲器上放置的是0x00008080，也就是該堆棧底部的指針的值。

就是說，StackSvc DCD SvcStackSpace + (SVC_STACK_LEGTH - 1)* 4 這條32位的偽指令，經(jīng)過編譯后，是在0x00008040(StackSvc)地址上放置SvcStackSpace地址值(0x00008080)。也就是把0x00008080賦給了SP了。

再看看地址0x00008080~0x00008044 上的內(nèi)容，全部是andeq r0,r0,r0。

從匯編指令格式來翻譯，andeq r0,r0,r0翻譯成16禁止代碼后，剛好是0x00000000。從而達到堆?？臻g清0的目的。